🌂Formal Grammar Description (BNF)

Backus-Naur Form (BNF) is a formal notation used to describe the syntax of programming languages

Grammar Notation

Example of BNF

Below is an example of a simple BNF grammar defining a basic arithmetic expression:

<expression> ::= <term> | <term> "+" <expression>
<term> ::= <factor> | <factor> "*" <term>
<factor> ::= <number> | "(" <expression> ")"
<number> ::= "0" | "1" | "2" | ... | "9"

This grammar describes expressions involving addition and multiplication of single-digit numbers, including the use of parentheses for grouping.

• <...>: Non-terminal symbols to be expanded

• ::=: Defined as

• |: Or (alternative choices)

• *: Zero or more occurrences

• +: One or more occurrences

• ?: Optional (zero or one occurrence)

• Literals: Enclosed in quotes (e.g., "+" or "(")

• Grouping: Square brackets [...]

• Comments: Indicated by

Maryl's grammar description (BNF)

<type> ::= "int"
        | "float"
        | "double"
        | "string"
        | "char"
        | "bool"
        | "void"
        | <list-type>
        | <const-type>
        | <struct-type>

<list-type> ::= "[]" <type>
<const-type> ::= "const" <type>
<struct-type> ::= "struct" <identifier> <block>
<expression> ::= <variable>
             | <literal>
             | <function-call>
             | <binary-expr>
             | <prefix-expr>
             | <postfix-expr>
             | <ternary-expr>
             | <grouped-expr>
             | <assignment>
             | <label>

<label> ::= <identifier> ":"
<variable> ::= <identifier>
<identifier> ::= <letter> <alphanumeric>*
             | "_" <alphanumeric>+

<literal> ::= <integer>
          | <double>
          | <bool>
          | <string>
          | <char>
          | <list>

<integer> ::= <digit>+
<double> ::= <digit>* "." <digit>+
<bool> ::= "true" | "false"
<string> ::= '"' <char>* '"'
<char> ::= "'" <char> "'"
<list> ::= "[" <expression> ("," <expression>)* "]"
<struct> ::= "{" <expression> ("," <expression>)* "}"

<function-call> ::= <identifier> "(" <expression-list>? ")"
<expression-list> ::= <expression> ("," <expression>)*

<binary-expr> ::= <expression> <binary-operator> <expression>
<binary-operator> ::= "+" | "-" | "|" | "&" | ">>" | "<<" | "^" | "*" | "**" | "/" | "%" | "==" | "!=" | ">" | ">=" | "<" | "<=" | "and" | "or"

<prefix-expr> ::= <prefix-operator> <expression>
<prefix-operator> ::= "!" | "-" | "++" | "--" | "~"

<postfix-expr> ::= <expression> <postfix-operator>
<postfix-operator> ::= "++" | "--"

<ternary-expr> ::= <expression> "?" <expression> ":" <expression>

<grouped-expr> ::= "(" <expression> ")"
<assignment> ::= <variable> <assign-operator> <expression>
<assign-operator> ::= "=" | "+=" | "-=" | "**=" | "*=" | "/=" | "%=" | "|=" | "&=" | "^=" | ">>=" | "<<="
<statement> ::= <declaration>
            | <expression-statement>
            | <if-statement>
            | <while-statement>
            | <return-statement>
            | <break-statement>
            | <continue-statement>

<declaration> ::= <variable-declaration> | <function-declaration>
<variable-declaration> ::= <type> <identifier> ("=" <expression>)? ";"
<function-declaration> ::= <type> <identifier> "(" <parameter-list>? ")" <block>
<parameter-list> ::= <type> <identifier> ("," <type> <identifier>)*
<function-body> ::= <block>
<block> ::= "{" <statement>* "}"

<expression-statement> ::= <expression> ";"

<if-statement> ::= "if" "(" <expression> ")" <block> <else-if>* <else>?
<else-if> ::= "else if" "(" <expression> ")" <block>
<else> ::= "else" <block>

<while-statement> ::= "while" "(" <expression> ")" <block>

<return-statement> ::= "return" <expression>? ";"

<break-statement> ::= "break" ";"
<continue-statement> ::= "continue" ";"

<import-statement> ::= "import" <string> ";"